ダークサイドの​​、​​をつけたくてもつけられない

タカハシ時計更新しました
・mojibansettingの値を微調整
・浮動小数点の関係で結果がきもちわるくなっていたので無理やり修正

```
// タカハシ時計(なめらか)
// Original: @yu4mogi@voskey.icalo.net
// https://voskey.icalo.net/notes/9da7az18ql
// Edited by @Higameshi@voskey.icalo.net

////設定部分
//ここで時計のサイズを調節してください
let clockscale = 0.8
//ここでスイープ/ステップを切り替える
let sweep = true
//文字盤の表示
let displaymojiban = true
//なんかサイズを変更すると文字盤がずれるので調節してください(たすけて)
let mojibansetting = -2.41
//ここで現在のタイムゾーンなどを設定してください(fpsは大きくすると重くなります)
let timezone = 9.0
let fps = 30
////設定部分おわり

// 現在時刻を取得して数値にして返す
@getCurrentnow(){
return ( Date:now() % (1000*60*60*12)) + (timezone % 24) * (1000*60*60)
}
// 各針の角度を計算
var now = 0
var angle_h = 0
var angle_m = 0
var angle_s = 0
var hand_h = ``
var hand_m = ``
var hand_s = ``
let sho = 0.03125
@quo(x) {((x[0] - x[0] % x[1]) / x[1])}
@shishagonyu(x) {(x[0]+x[1]/2 - ((x[0]+x[1]/2) % x[1]))}
@getTakahashi(){
now = getCurrentnow()
if (sweep) {
angle_h = ((360/(1000*60*60*12)) * now - 90)
angle_m = ((360/(1000*60*60)) * now - 90)
angle_s = ((360/(1000*60)) * now - 90)
} else {
angle_h = ((360/(60*60*12)) * quo([now 1000]) - 90)
angle_m = ((360/(60*60)) 10 quo([now (1000 * 10)]) - 90)
angle_s = ((360/(60)) * quo([now 1000]) - 90)
}
hand_h = $[position.y=0 $[rotate.deg={shishagonyu([angle_h sho])} :blank::blank::blank::takahashi_fankit:]]
hand_m = $[position.y=2 $[rotate.deg={shishagonyu([angle_m sho])} :blank::blank::blank:$[position.x=1 $[scale.x=1.41,y=0.70 :takahashi_fankit:]]]]
hand_s = $[position.y=4 $[rotate.deg={shishagonyu([angle_s sho])} :blank::blank::blank:$[position.x=2.5 $[scale.x=2,y=0.125 :takahashi_fankit:]]]]

return {hand_s}{Str:lf}{hand_m}{Str:lf}{hand_h}
}
//文字盤を表示
let clockcenter = -5.3
let clockradius = 20
var mojiban = ``
for (let i, 12) {
if (displaymojiban) {
mojiban = {mojiban}$[position.x={shishagonyu([clockradius*Math:cos((i-3)*(2*Math:PI)/12) sho])},y={shishagonyu([clockradius*Math:sin((i-3)*(2*Math:PI)/12) sho])} $[position.x={(i%2)*(-1)*5+2.5},y={shishagonyu([clockcenter+quo([i 2])*mojibansetting sho])} $[rotate.deg={-90 + i * (360/12)} :takahashi_fankit:]]]
}
if (i%2 !=0) {
mojiban = {mojiban}{Str:lf}
}
}

// 描画
let margin_before = {Str:lf}{Str:lf}{Str:lf}{Str:lf}
let margin_after = ``
@takahands() {
return {text: {margin_before}{Str:lf}{getTakahashi()}{Str:lf}{margin_after} size: clockscale}
}
@main(){
Ui:render([
Ui:C:mfm(takahands() "hands")
Ui:C:mfm({text: {mojiban}{Str:lf}{Str:lf} size: clockscale*0.5})
])
}
main()
@draw(){
Async:interval((1000 / fps), @(){Ui:get("hands").update(takahands())}, true) // 1/fps秒ごとに呼び出し
}
draw()
``` #タカハシ時計

タカハシ時計更新しました
・mojibansettingの値を微調整
・浮動小数点の関係で結果がきもちわるくなっていたので無理やり修正
諸事情につき再投稿しました

// タカハシ時計(なめらか)
// Original: @yu4mogi@voskey.icalo.net
// https://voskey.icalo.net/notes/9da7az18ql
// Edited by @Higameshi@voskey.icalo.net

////設定部分
//ここで時計のサイズを調節してください
let clockscale = 0.8
//ここでスイープ/ステップを切り替える
let sweep = true
//文字盤の表示
let displaymojiban = true
//なんかサイズを変更すると文字盤がずれるので調節してください(たすけて)
let mojibansetting = -2.41
//ここで現在のタイムゾーンなどを設定してください(fpsは大きくすると重くなります)
let timezone = 9.0
let fps = 30
////設定部分おわり

// 現在時刻を取得して数値にして返す
@getCurrentnow(){
  return ( Date:now() % (1000*60*60*12)) + (timezone % 24) * (1000*60*60)
}
// 各針の角度を計算
var now = 0
var angle_h = 0
var angle_m = 0
var angle_s = 0
var hand_h = ``
var hand_m = ``
var hand_s = ``
let sho = 0.03125
@quo(x) {((x[0] - x[0] % x[1]) / x[1])}
@shishagonyu(x) {(x[0]+x[1]/2 - ((x[0]+x[1]/2) % x[1]))}
@getTakahashi(){
  now = getCurrentnow()
  if (sweep) {
    angle_h = ((360/(1000*60*60*12)) * now - 90)
    angle_m = ((360/(1000*60*60)) * now - 90)
    angle_s = ((360/(1000*60)) * now - 90)
  } else {
    angle_h = ((360/(60*60*12)) * quo([now 1000]) - 90)
    angle_m = ((360/(60*60)) * 10 * quo([now (1000 * 10)]) - 90)
    angle_s = ((360/(60)) * quo([now 1000]) - 90)
  }
  hand_h = `$[position.y=0 $[rotate.deg={shishagonyu([angle_h sho])} :blank::blank::blank::takahashi_fankit:]]`
  hand_m = `$[position.y=2 $[rotate.deg={shishagonyu([angle_m sho])} :blank::blank::blank:$[position.x=1 $[scale.x=1.41,y=0.70 :takahashi_fankit:]]]]`
  hand_s = `$[position.y=4 $[rotate.deg={shishagonyu([angle_s sho])} :blank::blank::blank:$[position.x=2.5 $[scale.x=2,y=0.125 :takahashi_fankit:]]]]`
  
  return `{hand_s}{Str:lf}{hand_m}{Str:lf}{hand_h}`
}
//文字盤を表示
let clockcenter = -5.3
let clockradius = 20
var mojiban = ``
for (let i, 12) {
	if (displaymojiban) {
	  mojiban = `{mojiban}$[position.x={shishagonyu([clockradius*Math:cos((i-3)*(2*Math:PI)/12) sho])},y={shishagonyu([clockradius*Math:sin((i-3)*(2*Math:PI)/12) sho])} $[position.x={(i%2)*(-1)*5+2.5},y={shishagonyu([clockcenter+quo([i 2])*mojibansetting sho])} $[rotate.deg={-90 + i * (360/12)} :takahashi_fankit:]]]`
	}
	if (i%2 !=0) {
	  mojiban = `{mojiban}{Str:lf}`
	}
}

// 描画
let margin_before = `{Str:lf}{Str:lf}{Str:lf}{Str:lf}`
let margin_after = ``
@takahands() {
  return {text: `{margin_before}{Str:lf}{getTakahashi()}{Str:lf}{margin_after}` size: clockscale}
}
@main(){
  Ui:render([
    Ui:C:mfm(takahands() "hands")
    Ui:C:mfm({text: `{mojiban}{Str:lf}{Str:lf}` size: clockscale*0.5})
  ])
}
main()
@draw(){
  Async:interval((1000 / fps), @(){Ui:get("hands").update(takahands())}, true) // 1/fps秒ごとに呼び出し
}
draw()